dhcp: upgrade to 4.1.1-P1

from version 4.1.0

changes:
  original .bb file is based on dhcp3, whose build system differs from
  dhcp 4.x, add a new dhcp4.inc and preserve dhcp3.inc for reference,
  this should fix the conf file location bug of dhclient/dhcpd 4.1.0

  - defining _PATH_DHC{LIENT,PD}_CONF in make parameter no longer works,
    put these definition to includes/site.h
  - delete upstream version of conf files, which are not used, and
    with an installation path hardcoded to ${sysconfdir}
  - similar thing happen for leases file, use new configure option to
    specify
  - RANLIB, LIBDIR, etc. as make parameter are no longer necessary

Signed-off-by: Qing He <qing.he@intel.com>

7 files changed, 88 insertions, 4 deletions

diff --git a/meta/packages/dhcp/files/dhcp-3.0.3-dhclient-dbus.patch b/meta/packages/dhcp/dhcp-4.1.1-P1/dhcp-3.0.3-dhclient-dbus.patch
index 579d72f..579d72f 100644
--- a/meta/packages/dhcp/files/dhcp-3.0.3-dhclient-dbus.patch
+++ b/meta/packages/dhcp/dhcp-4.1.1-P1/dhcp-3.0.3-dhclient-dbus.patch
diff --git a/meta/packages/dhcp/files/fixincludes.patch b/meta/packages/dhcp/dhcp-4.1.1-P1/fixincludes.patch
index 91d99cc..91d99cc 100644
--- a/meta/packages/dhcp/files/fixincludes.patch
+++ b/meta/packages/dhcp/dhcp-4.1.1-P1/fixincludes.patch
diff --git a/meta/packages/dhcp/files/noattrmode.patch b/meta/packages/dhcp/dhcp-4.1.1-P1/noattrmode.patch
index 5c766d6..5c766d6 100644
--- a/meta/packages/dhcp/files/noattrmode.patch
+++ b/meta/packages/dhcp/dhcp-4.1.1-P1/noattrmode.patch
diff --git a/meta/packages/dhcp/dhcp-4.1.1-P1/site.h b/meta/packages/dhcp/dhcp-4.1.1-P1/site.h
new file mode 100644
index 0000000..2289554
--- /dev/null
+++ b/meta/packages/dhcp/dhcp-4.1.1-P1/site.h
@@ -0,0 +1,21 @@
+/*
+ * define config file location in ${S}/includes/site.h
+ * still need to take care of installation path (${sysconfdir}/dhcpd.conf)
+ *
+ * 7/22/2010 - qhe
+ */
+
+/* Define this if you want DNS update functionality to be available. */
+
+#define NSUPDATE
+
+/* Define this if you aren't debugging and you want to save memory
+   (potentially a _lot_ of memory) by allocating leases in chunks rather
+   than one at a time. */
+
+#define COMPACT_LEASES
+
+
+/* local */
+#define _PATH_DHCPD_CONF     "/etc/dhcp/dhcpd.conf"
+#define _PATH_DHCLIENT_CONF  "/etc/dhcp/dhclient.conf"
diff --git a/meta/packages/dhcp/dhcp_4.1.0.bb b/meta/packages/dhcp/dhcp3.inc
index cb6b267..3f68f45 100644
--- a/meta/packages/dhcp/dhcp_4.1.0.bb
+++ b/meta/packages/dhcp/dhcp3.inc
@@ -1,11 +1,11 @@
 SECTION = "console/network"
 DESCRIPTION = "Internet Software Consortium DHCP package"
 HOMEPAGE = "http://www.isc.org/"
-LICENSE = "BSD"
-PR = "r7"
+
+LICENSE = "ISC"
+LIC_FILES_CHKSUM = "file://LICENSE;beginline=4;md5=bb6fd41f5895b67088ebea61ad365e74"
+
 SRC_URI = "ftp://ftp.isc.org/isc/dhcp/dhcp-${PV}.tar.gz \
-	   file://fixincludes.patch;patch=1 \
-	   file://dhcp-3.0.3-dhclient-dbus.patch;patch=1;pnum=0 \
 	   file://init-relay file://default-relay \
 	   file://init-server file://default-server \
 	   file://dhclient.conf file://dhcpd.conf"
diff --git a/meta/packages/dhcp/dhcp4.inc b/meta/packages/dhcp/dhcp4.inc
new file mode 100644
index 0000000..7652b94
--- /dev/null
+++ b/meta/packages/dhcp/dhcp4.inc
@@ -0,0 +1,57 @@
+SECTION = "console/network"
+DESCRIPTION = "Internet Software Consortium DHCP package"
+HOMEPAGE = "http://www.isc.org/"
+
+LICENSE = "ISC"
+LIC_FILES_CHKSUM = "file://LICENSE;beginline=4;md5=bb6fd41f5895b67088ebea61ad365e74"
+
+SRC_URI = "ftp://ftp.isc.org/isc/dhcp/dhcp-${PV}.tar.gz \
+           file://site.h \
+	   file://init-relay file://default-relay \
+	   file://init-server file://default-server \
+	   file://dhclient.conf file://dhcpd.conf"
+
+inherit autotools
+
+TARGET_CFLAGS += "-D_GNU_SOURCE"
+EXTRA_OECONF = "--with-srv-lease-file=${localstatedir}/lib/dhcp/dhcpd.leases \
+                --with-srv6-lease-file=${localstatedir}/lib/dhcp/dhcpd6.leases \
+                --with-cli-lease-file=${localstatedir}/lib/dhcp/dhclient.leases \
+                --with-cli6-lease-file=${localstatedir}/lib/dhcp/dhclient6.leases"
+
+do_compile_prepend () {
+	cp -f ${WORKDIR}/site.h ${S}/includes
+}
+
+do_install_append () {
+	install -d ${D}${sysconfdir}/init.d
+	install -d ${D}${sysconfdir}/default
+	install -d ${D}${sysconfdir}/dhcp
+	install -m 0755 ${WORKDIR}/init-relay ${D}${sysconfdir}/init.d/dhcp-relay
+	install -m 0644 ${WORKDIR}/default-relay ${D}${sysconfdir}/default/dhcp-relay
+	install -m 0755 ${WORKDIR}/init-server ${D}${sysconfdir}/init.d/dhcp-server
+	install -m 0644 ${WORKDIR}/default-server ${D}${sysconfdir}/default/dhcp-server
+
+	rm -f ${D}${sysconfdir}/dhclient.conf
+	rm -f ${D}${sysconfdir}/dhcpd.conf
+	install -m 0644 ${WORKDIR}/dhclient.conf ${D}${sysconfdir}/dhcp/dhclient.conf
+	install -m 0644 ${WORKDIR}/dhcpd.conf ${D}${sysconfdir}/dhcp/dhcpd.conf
+
+	install -d ${D}${base_sbindir}/
+	mv ${D}${sbindir}/dhclient ${D}${base_sbindir}/
+	install -m 0755 ${S}/client/scripts/linux ${D}${base_sbindir}/dhclient-script
+}
+
+PACKAGES += "dhcp-server dhcp-client dhcp-relay dhcp-omshell"
+FILES_${PN} = ""
+FILES_dhcp-server = "${sbindir}/dhcpd ${sysconfdir}/init.d/dhcp-server ${sysconfdir}/default/dhcp-server ${sysconfdir}/dhcp/dhcpd.conf"
+FILES_dhcp-relay = "${sbindir}/dhcrelay ${sysconfdir}/init.d/dhcp-relay ${sysconfdir}/default/dhcp-relay"
+
+FILES_dhcp-client = "${base_sbindir}/dhclient ${base_sbindir}/dhclient-script ${sysconfdir}/dhcp/dhclient.conf"
+RDEPENDS_dhcp-client = "bash"
+
+FILES_dhcp-omshell = "${bindir}/omshell"
+
+CONFFILES_dhcp-server_nylon = "/etc/dhcp/dhcpd.conf"
+CONFFILES_dhcp-relay_nylon = "/etc/default/dhcp-relay"
+CONFFILES_dhcp-client_nylon = "/etc/dhcp/dhclient.conf"
diff --git a/meta/packages/dhcp/dhcp_4.1.1-P1.bb b/meta/packages/dhcp/dhcp_4.1.1-P1.bb
new file mode 100644
index 0000000..c7025f8
--- /dev/null
+++ b/meta/packages/dhcp/dhcp_4.1.1-P1.bb
@@ -0,0 +1,6 @@
+require dhcp4.inc
+
+PR = "r0"
+
+SRC_URI += "file://fixincludes.patch \
+            file://dhcp-3.0.3-dhclient-dbus.patch;striplevel=0"