summaryrefslogtreecommitdiffstats
path: root/tinySIP/ragel/tsip_parser_header_Security_Verify.rl
blob: ea24ee1c70eb42053b9bca3130cb91de02b07c02 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
/*
* Copyright (C) 2010-2011 Mamadou Diop.
*
* Contact: Mamadou Diop <diopmamadou(at)doubango[dot]org>
*	
* This file is part of Open Source Doubango Framework.
*
* DOUBANGO is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*	
* DOUBANGO is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
* GNU General Public License for more details.
*	
* You should have received a copy of the GNU General Public License
* along with DOUBANGO.
*
*/

/**@file tsip_header_Security_Verify.c
 * @brief SIP Security-Verify header as per RFC 3329.
 *
 * @author Mamadou Diop <diopmamadou(at)doubango[dot]org>
 *

 */
#include "tinysip/headers/tsip_header_Security_Verify.h"

#include "tinysip/parsers/tsip_parser_uri.h"

#include "tsk_debug.h"
#include "tsk_memory.h"
#include "tsk_time.h"

#include <string.h>



/***********************************
*	Ragel state machine.
*/
%%{
	machine tsip_machine_parser_header_Security_Verify;

	# Includes
	include tsip_machine_utils "./ragel/tsip_machine_utils.rl";
	
	action tag{
		tag_start = p;
	}
	
	action create_securityverify{
		if(!curr_securityverify){
			curr_securityverify = tsip_header_Security_Verify_create_null();
		}
	}

	action add_securityverify{
		if(curr_securityverify){
			tsk_list_push_back_data(hdr_securityverifies, ((void**) &curr_securityverify));
		}
	}
	
	action parse_mech{
		if(curr_securityverify){
			TSK_PARSER_SET_STRING(curr_securityverify->mech);
		}
	}

	action parse_port_s{
		if(curr_securityverify){
			TSK_PARSER_SET_INT(curr_securityverify->port_s);
		}
	}

	action parse_port_c{
		if(curr_securityverify){
			TSK_PARSER_SET_INT(curr_securityverify->port_c);
		}
	}

	action parse_spi_s{
		if(curr_securityverify){
			TSK_PARSER_SET_UINT(curr_securityverify->spi_s);
		}
	}

	action parse_spi_c{
		if(curr_securityverify){
			TSK_PARSER_SET_UINT(curr_securityverify->spi_c);
		}
	}

	action parse_ealg{
		if(curr_securityverify){
			TSK_PARSER_SET_STRING(curr_securityverify->ealg);
		}
	}

	action parse_alg{
		if(curr_securityverify){
			TSK_PARSER_SET_STRING(curr_securityverify->alg);
		}
	}

	action parse_prot{
		if(curr_securityverify){
			TSK_PARSER_SET_STRING(curr_securityverify->prot);
		}
	}

	action parse_preference{
		if(curr_securityverify){
			TSK_PARSER_SET_DOUBLE(curr_securityverify->q);
		}
	}

	action parse_param{
		if(curr_securityverify){
			TSK_PARSER_ADD_PARAM(TSIP_HEADER_PARAMS(curr_securityverify));
		}
	}

	action eob{
	}

	mech_extension = generic_param>tag %parse_param;
	port_s = "port-s"i EQUAL DIGIT+>tag %parse_port_s;
	port_c = "port-c"i EQUAL DIGIT+>tag %parse_port_c;
	spi_s = "spi-s"i EQUAL DIGIT+>tag %parse_spi_s;
	spi_c = "spi-c"i EQUAL DIGIT+>tag %parse_spi_c;
	ealg = "ealg"i EQUAL token>tag %parse_ealg;
	alg = "alg"i EQUAL token>tag %parse_alg;
	prot = "prot"i EQUAL token>tag %parse_prot;
	preference = "q"i EQUAL qvalue>tag %parse_preference;
	mech_parameters = (preference | prot | alg | ealg | spi_c | spi_s | port_c | port_s) @1 | mech_extension @0;
	mechanism_name = token>tag %parse_mech;
	sec_mechanism = (mechanism_name ( SEMI mech_parameters )*) >create_securityverify %add_securityverify;
	Security_Verify = "Security-Verify"i HCOLON sec_mechanism ( COMMA sec_mechanism )*;

	# Entry point
	main := Security_Verify :>CRLF @eob;

}%%

tsip_header_Security_Verify_t* tsip_header_Security_Verify_create()
{
	return tsk_object_new(TSIP_HEADER_SECURITY_VERIFY_VA_ARGS());
}

tsip_header_Security_Verify_t* tsip_header_Security_Verify_create_null()
{
	return tsip_header_Security_Verify_create();
}

int tsip_header_Security_Verify_serialize(const tsip_header_t* header, tsk_buffer_t* output)
{
	if(header){
		const tsip_header_Security_Verify_t *Security_Verify = (const tsip_header_Security_Verify_t *)header;
		int ret = 0;
		
		// ipsec-3gpp; alg=hmac-md5-96; ealg=des-ede3-cbc; spi-c=1111; spi-s=2222; port-c=5062; port-s=5064
		if(tsk_striequals(Security_Verify->mech, "ipsec-3gpp")){
			ret = tsk_buffer_append_2(output, "%s%s%s%s%s%s%s;spi-c=%u;spi-s=%u;port-c=%u;port-s=%u", 
				Security_Verify->mech,
				
				Security_Verify->alg ? ";alg=" : "",
				Security_Verify->alg ? Security_Verify->alg : "",
				
				Security_Verify->ealg ? ";ealg=" : "",
				Security_Verify->ealg ? Security_Verify->ealg : "",

				Security_Verify->prot ? ";prot=" : "",
				Security_Verify->prot ? Security_Verify->prot : "",
				
				Security_Verify->spi_c,
				Security_Verify->spi_s,
				Security_Verify->port_c,
				Security_Verify->port_s
				);
		}
		else if(Security_Verify->mech){
			tsk_buffer_append(output, Security_Verify->mech, tsk_strlen(Security_Verify->mech));
		}

		if(Security_Verify->q >= 0){
			/* qvalue	=  	("0" [ "." 0*3DIGIT ] ) / ( "1" [ "." 0*3("0") ] ) */
			tsk_buffer_append_2(output, ";q=%1.3f", Security_Verify->q);
		}
		
		return ret;
	}

	return -1;
}

tsip_header_Security_Verifies_L_t *tsip_header_Security_Verify_parse(const char *data, tsk_size_t size)
{
	int cs = 0;
	const char *p = data;
	const char *pe = p + size;
	const char *eof = pe;
	tsip_header_Security_Verifies_L_t *hdr_securityverifies = tsk_list_create();
	
	const char *tag_start = tsk_null;
	tsip_header_Security_Verify_t *curr_securityverify = tsk_null;

	%%write data;
	(void)(eof);
	(void)(tsip_machine_parser_header_Security_Verify_first_final);
	(void)(tsip_machine_parser_header_Security_Verify_error);
	(void)(tsip_machine_parser_header_Security_Verify_en_main);
	%%write init;
	%%write exec;
	
	if( cs < %%{ write first_final; }%% ){
		TSK_DEBUG_ERROR("Failed to parse 'Security-Verify' header.");
		TSK_OBJECT_SAFE_FREE(curr_securityverify);
		TSK_OBJECT_SAFE_FREE(hdr_securityverifies);
	}
	
	return hdr_securityverifies;
}





//========================================================
//	Security_Verify header object definition
//

static tsk_object_t* tsip_header_Security_Verify_ctor(tsk_object_t *self, va_list * app)
{
	tsip_header_Security_Verify_t *Security_Verify = self;
	if(Security_Verify){

		TSIP_HEADER(Security_Verify)->type = tsip_htype_Security_Verify;
		TSIP_HEADER(Security_Verify)->serialize = tsip_header_Security_Verify_serialize;

		Security_Verify->q = -1;
	}
	else{
		TSK_DEBUG_ERROR("Failed to create new Security_Verify header.");
	}
	return self;
}

static tsk_object_t* tsip_header_Security_Verify_dtor(tsk_object_t *self)
{
	tsip_header_Security_Verify_t *Security_Verify = self;
	if(Security_Verify){
		TSK_FREE(Security_Verify->mech);
		TSK_FREE(Security_Verify->alg);
		TSK_FREE(Security_Verify->prot);
		TSK_FREE(Security_Verify->mod);
		TSK_FREE(Security_Verify->ealg);

		TSK_OBJECT_SAFE_FREE(TSIP_HEADER_PARAMS(Security_Verify));
	}
	else{
		TSK_DEBUG_ERROR("Null Security_Verify header.");
	}

	return self;
}

static const tsk_object_def_t tsip_header_Security_Verify_def_s = 
{
	sizeof(tsip_header_Security_Verify_t),
	tsip_header_Security_Verify_ctor,
	tsip_header_Security_Verify_dtor,
	tsk_null
};
const tsk_object_def_t *tsip_header_Security_Verify_def_t = &tsip_header_Security_Verify_def_s;

OpenPOWER on IntegriCloud