summaryrefslogtreecommitdiffstats
path: root/meta/recipes-devtools/libtool/nativesdk-libtool_2.4.2.bb
blob: fff15e916dc0341d75af59a365dd251f5aa557e2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
require libtool-${PV}.inc

PR = "${INC_PR}.0"

FILESEXTRAPATHS =. "${FILE_DIRNAME}/libtool:"

SRC_URI += "file://prefix.patch"
SRC_URI += "file://fixinstall.patch"

inherit nativesdk

S = "${WORKDIR}/libtool-${PV}"
FILES_${PN} += "${datadir}/libtool/*"

do_configure_prepend () {
	# Remove any existing libtool m4 since old stale versions would break
	# any upgrade
	rm -f ${STAGING_DATADIR}/aclocal/libtool.m4
	rm -f ${STAGING_DATADIR}/aclocal/lt*.m4
}

do_install () {
	autotools_do_install
	install -d ${D}${bindir}/
	install -m 0755 ${HOST_SYS}-libtool ${D}${bindir}/
}

SYSROOT_PREPROCESS_FUNCS += "libtoolnativesdk_sysroot_preprocess"

libtoolnativesdk_sysroot_preprocess () {
	install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
	install -m 755 ${D}${bindir}/${HOST_SYS}-libtool ${SYSROOT_DESTDIR}${bindir_crossscripts}/${HOST_SYS}-libtool
}

export CONFIG_SHELL="/bin/bash"
OpenPOWER on IntegriCloud