From 942b3b1d37239ef5ecf06f480f8c84b3f4da38a2 Mon Sep 17 00:00:00 2001
From: Scott Garman <scott.a.garman@intel.com>
Date: Tue, 25 Jan 2011 15:29:31 -0800
Subject: docbook-dsssl-stylesheets: new recipe v1.79

Recipe migrated from OpenEmbedded.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 .../docbook-dsssl-stylesheets-native_1.79.bb       | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 meta/recipes-devtools/docbook-dsssl-stylesheets/docbook-dsssl-stylesheets-native_1.79.bb

(limited to 'meta/recipes-devtools/docbook-dsssl-stylesheets')

diff --git a/meta/recipes-devtools/docbook-dsssl-stylesheets/docbook-dsssl-stylesheets-native_1.79.bb b/meta/recipes-devtools/docbook-dsssl-stylesheets/docbook-dsssl-stylesheets-native_1.79.bb
new file mode 100644
index 0000000..92de638
--- /dev/null
+++ b/meta/recipes-devtools/docbook-dsssl-stylesheets/docbook-dsssl-stylesheets-native_1.79.bb
@@ -0,0 +1,52 @@
+SUMMARY = "DSSSL stylesheets used to transform SGML and XML DocBook files"
+DESCRIPTION = "DSSSL stylesheets used to transform SGML and XML DocBook files"
+HOMEPAGE= "http://docbook.sourceforge.net"
+# Simple persmissive
+LICENSE = "DSSSL"
+LIC_FILES_CHKSUM = "file://README;beginline=41;endline=74;md5=875385159b2ee76ecf56136ae7f542d6"
+
+DEPENDS = "sgml-common-native"
+
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/docbook/docbook-dsssl-${PV}.tar.bz2"
+
+SRC_URI[md5sum] = "bc192d23266b9a664ca0aba4a7794c7c"
+SRC_URI[sha256sum] = "2f329e120bee9ef42fbdd74ddd60e05e49786c5a7953a0ff4c680ae6bdf0e2bc"
+
+S = "${WORKDIR}/docbook-dsssl-${PV}"
+
+inherit native
+
+SYSROOT_PREPROCESS_FUNCS += "docbook_dssl_stylesheets_native_mangle"
+
+do_install () {
+	# Refer to http://www.linuxfromscratch.org/blfs/view/stable/pst/docbook-dsssl.html
+	# for details.
+	install -d ${D}${bindir}
+	install -m 0755 bin/collateindex.pl ${D}${bindir}
+
+	install -d ${D}${datadir}/sgml/docbook/dsssl-stylesheets-${PV}
+	install -m 0644 catalog ${D}${datadir}/sgml/docbook/dsssl-stylesheets-${PV}
+	cp -PpRr common ${D}${datadir}/sgml/docbook/dsssl-stylesheets-${PV}
+
+	install-catalog --add ${sysconfdir}/sgml/dsssl-docbook-stylesheets.cat \
+		${D}${datadir}/sgml/docbook/dsssl-stylesheets-${PV}/catalog
+
+	install-catalog --add ${sysconfdir}/sgml/dsssl-docbook-stylesheets.cat \
+		${D}${datadir}/sgml/docbook/dsssl-stylesheets-${PV}/common/catalog
+
+	install-catalog --add ${sysconfdir}/sgml/sgml-docbook.cat \
+		${sysconfdir}/sgml/dsssl-docbook-stylesheets.cat
+
+	# Move these to the image directory so they get staged properly.
+	install -d ${D}${sysconfdir}/sgml
+	cp ${sysconfdir}/sgml/dsssl-docbook-stylesheets.cat ${D}${sysconfdir}/sgml/
+	cp ${sysconfdir}/sgml/sgml-docbook.cat ${D}${sysconfdir}/sgml/
+	cp ${sysconfdir}/sgml/catalog ${D}${sysconfdir}/sgml/
+}
+
+docbook_dssl_stylesheets_native_mangle () {
+	# Remove the image directory path ${D} from the .cat file.
+	sed -i -e "s|${D}||g" ${SYSROOT_DESTDIR}${sysconfdir}/sgml/dsssl-docbook-stylesheets.cat
+}
-- 
cgit v1.1