1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
|
/* $OpenBSD: locore.S,v 1.18 1998/09/15 10:58:53 pefo Exp $ */
/*-
* Copyright (c) 1992, 1993
* The Regents of the University of California. All rights reserved.
*
* This code is derived from software contributed to Berkeley by
* Digital Equipment Corporation and Ralph Campbell.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
* 4. Neither the name of the University nor the names of its contributors
* may be used to endorse or promote products derived from this software
* without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*
* Copyright (C) 1989 Digital Equipment Corporation.
* Permission to use, copy, modify, and distribute this software and
* its documentation for any purpose and without fee is hereby granted,
* provided that the above copyright notice appears in all copies.
* Digital Equipment Corporation makes no representations about the
* suitability of this software for any purpose. It is provided "as is"
* without express or implied warranty.
*
* from: Header: /sprite/src/kernel/mach/ds3100.md/RCS/loMem.s,
* v 1.1 89/07/11 17:55:04 nelson Exp SPRITE (DECWRL)
* from: Header: /sprite/src/kernel/mach/ds3100.md/RCS/machAsm.s,
* v 9.2 90/01/29 18:00:39 shirriff Exp SPRITE (DECWRL)
* from: Header: /sprite/src/kernel/vm/ds3100.md/vmPmaxAsm.s,
* v 1.1 89/07/10 14:27:41 nelson Exp SPRITE (DECWRL)
*
* from: @(#)locore.s 8.5 (Berkeley) 1/4/94
* JNPR: locore.S,v 1.6.2.1 2007/08/29 12:24:49 girish
* $FreeBSD$
*/
/*
* FREEBSD_DEVELOPERS_FIXME
* The start routine below was written for a multi-core CPU
* with each core being hyperthreaded. This serves as an example
* for a complex CPU architecture. For a different CPU complex
* please make necessary changes to read CPU-ID etc.
* A clean solution would be to have a different locore file for
* each CPU type.
*/
/*
* Contains code that is the first executed at boot time plus
* assembly language support routines.
*/
#include <machine/asm.h>
#include <machine/cpu.h>
#include <machine/cpuregs.h>
#include <machine/regnum.h>
#include "assym.s"
.data
#ifdef YAMON
GLOBAL(fenvp)
.space 4 # Assumes mips32? Is that OK?
#endif
.set noreorder
.text
GLOBAL(btext)
ASM_ENTRY(_start)
VECTOR(_locore, unknown)
/* UNSAFE TO USE a0..a3, need to preserve the args from boot loader */
mtc0 zero, MIPS_COP_0_CAUSE # Clear soft interrupts
#if defined(CPU_CNMIPS)
/*
* t1: Bits to set explicitly:
* Enable FPU
*/
/* Set these bits */
li t1, (MIPS_SR_COP_0_BIT | MIPS_SR_PX | MIPS_SR_KX | MIPS_SR_UX | MIPS_SR_SX | MIPS_SR_BEV)
/* Reset these bits */
li t0, ~(MIPS_SR_DE | MIPS_SR_SOFT_RESET | MIPS_SR_ERL | MIPS_SR_EXL | MIPS_SR_INT_IE | MIPS_SR_COP_2_BIT)
#elif defined (CPU_RMI) || defined (CPU_NLM)
/* Set these bits */
li t1, (MIPS_SR_COP_2_BIT | MIPS_SR_COP_0_BIT | MIPS_SR_KX | MIPS_SR_UX)
/* Reset these bits */
li t0, ~(MIPS_SR_BEV | MIPS_SR_SOFT_RESET | MIPS_SR_INT_IE)
#else
/*
* t0: Bits to preserve if set:
* Soft reset
* Boot exception vectors (firmware-provided)
*/
li t0, (MIPS_SR_BEV | MIPS_SR_SOFT_RESET)
/*
* t1: Bits to set explicitly:
* Enable FPU
*/
li t1, MIPS_SR_COP_1_BIT
#ifdef __mips_n64
or t1, MIPS_SR_KX | MIPS_SR_SX | MIPS_SR_UX
#endif
#endif
/*
* Read coprocessor 0 status register, clear bits not
* preserved (namely, clearing interrupt bits), and set
* bits we want to explicitly set.
*/
mfc0 t2, MIPS_COP_0_STATUS
and t2, t0
or t2, t1
mtc0 t2, MIPS_COP_0_STATUS
COP0_SYNC
/* Make sure KSEG0 is cached */
li t0, MIPS_CCA_CACHED
mtc0 t0, MIPS_COP_0_CONFIG
COP0_SYNC
/*xxximp
* now that we pass a0...a3 to the platform_init routine, do we need
* to stash this stuff here?
*/
#ifdef YAMON
/* Save YAMON boot environment pointer */
sw a2, _C_LABEL(fenvp)
#endif
#if defined(CPU_CNMIPS) && defined(SMP)
.set push
.set mips32r2
rdhwr t2, $0
beqz t2, 1f
nop
j octeon_ap_wait
nop
.set pop
1:
#endif
/*
* Initialize stack and call machine startup.
*/
PTR_LA sp, _C_LABEL(pcpu_space)
PTR_ADDU sp, (PAGE_SIZE * 2) - CALLFRAME_SIZ
REG_S zero, CALLFRAME_RA(sp) # Zero out old ra for debugger
REG_S zero, CALLFRAME_SP(sp) # Zero out old fp for debugger
PTR_LA gp, _C_LABEL(_gp)
/* Call the platform-specific startup code. */
jal _C_LABEL(platform_start)
nop
PTR_LA sp, _C_LABEL(thread0)
PTR_L a0, TD_PCB(sp)
REG_LI t0, ~7
and a0, a0, t0
PTR_SUBU sp, a0, CALLFRAME_SIZ
jal _C_LABEL(mi_startup) # mi_startup(frame)
sw zero, CALLFRAME_SIZ - 8(sp) # Zero out old fp for debugger
PANIC("Startup failed!")
VECTOR_END(_locore)
|
