1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
/*-
* Copyright (c) [year] [your name]
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*
* $Id$
*/
#include "assym.s"
#include <machine/asm.h>
#include <machine/asmacros.h>
__FBSDID("$FreeBSD$");
#include <sys/errno.h>
/*
* copystr(9)
* <v0>int copystr(<a0>const void *src, <a1>void *dst, <a2>size_t len,
* <a3>size_t *done)
*/
ENTRY(copystr)
.set noreorder
.set noat
move v0, zero
beqz a2, 2f
move t1, zero
1: subu a2, 1
lbu t0, 0(a0)
addu a0, 1
sb t0, 0(a1)
addu a1, 1
beqz t0, 3f /* NULL - end of string*/
addu t1, 1
bnez a2, 1b
nop
2: /* ENAMETOOLONG */
li v0, ENAMETOOLONG
3: /* done != NULL -> how many bytes were copied */
beqz a3, 4f
nop
sw t1, 0(a3)
4: jr ra
nop
.set reorder
.set at
END(copystr)
/*
* int copyinstr(void *uaddr, void *kaddr, size_t maxlen, size_t *lencopied)
* Copy a NIL-terminated string, at most maxlen characters long, from the
* user's address space. Return the number of characters copied (including
* the NIL) in *lencopied. If the string is too long, return ENAMETOOLONG;
* else return 0 or EFAULT.
*/
LEAF(copyinstr)
.set noreorder
.set noat
lw t2, pcpup
lw v1, PC_CURPCB(t2)
la v0, _C_LABEL(copystrerr)
blt a0, zero, _C_LABEL(copystrerr)
sw v0, PCB_ONFAULT(v1)
move t0, a2
beq a2, zero, 4f
1:
lbu v0, 0(a0)
subu a2, a2, 1
beq v0, zero, 2f
sb v0, 0(a1)
addu a0, a0, 1
bne a2, zero, 1b
addu a1, a1, 1
4:
li v0, ENAMETOOLONG
2:
beq a3, zero, 3f
subu a2, t0, a2
sw a2, 0(a3)
3:
j ra # v0 is 0 or ENAMETOOLONG
sw zero, PCB_ONFAULT(v1)
.set reorder
.set at
END(copyinstr)
/*
* int copyoutstr(void *uaddr, void *kaddr, size_t maxlen, size_t *lencopied);
* Copy a NIL-terminated string, at most maxlen characters long, into the
* user's address space. Return the number of characters copied (including
* the NIL) in *lencopied. If the string is too long, return ENAMETOOLONG;
* else return 0 or EFAULT.
*/
LEAF(copyoutstr)
.set noreorder
.set noat
lw t2, pcpup
lw v1, PC_CURPCB(t2)
la v0, _C_LABEL(copystrerr)
blt a1, zero, _C_LABEL(copystrerr)
sw v0, PCB_ONFAULT(v1)
move t0, a2
beq a2, zero, 4f
1:
lbu v0, 0(a0)
subu a2, a2, 1
beq v0, zero, 2f
sb v0, 0(a1)
addu a0, a0, 1
bne a2, zero, 1b
addu a1, a1, 1
4:
li v0, ENAMETOOLONG
2:
beq a3, zero, 3f
subu a2, t0, a2
sw a2, 0(a3)
3:
j ra # v0 is 0 or ENAMETOOLONG
sw zero, PCB_ONFAULT(v1)
.set reorder
.set at
END(copyoutstr)
LEAF(copystrerr)
sw zero, PCB_ONFAULT(v1)
j ra
li v0, EFAULT # return EFAULT
END(copystrerr)
|
