blob: 4cf70bfeef81df849a6927799e38299ae71d409a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
#!/bin/sh
#
# $FreeBSD$
#
# Modify this to suit your needs. The "$1" is the map name, eg. "auto_master".
# To debug, simply run this script with map name as the only parameter. It's
# supposed to output map contents ("key location" pairs) to standard output.
SEARCHBASE="ou=$1,dc=example,dc=com"
ENTRY_ATTRIBUTE="cn"
VALUE_ATTRIBUTE="automountInformation"
/usr/local/bin/ldapsearch -LLL -x -o ldif-wrap=no -b "$SEARCHBASE" "$ENTRY_ATTRIBUTE" "$VALUE_ATTRIBUTE" | awk '
$1 == "'$ENTRY_ATTRIBUTE':" {
key = $2
}
$1 == "'$VALUE_ATTRIBUTE':" {
for (i = 2; i <= NF; i++) {
value[i] = $(i)
}
nvalues = NF
b64 = 0
}
# Double colon after attribute name means the value is in Base64.
$1 == "'$VALUE_ATTRIBUTE'::" {
for (i = 2; i <= NF; i++) {
value[i] = $(i)
}
nvalues = NF
b64 = 1
}
# Empty line - end of record.
NF == 0 && key != "" && nvalues > 0 {
printf "%s%s", key, OFS
for (i = 2; i < nvalues; i++) {
printf "%s%s", value[i], OFS
}
if (b64 == 1) {
printf "%s", value[nvalues] | "b64decode -rp"
close("b64decode -rp")
printf "%s", ORS
} else {
printf "%s%s", value[nvalues], ORS
}
}
NF == 0 {
key = ""
nvalues = 0
delete value
}
'
|
