Copy _setjmp.S from libc in preparation for loader-specific version.

3 files changed, 209 insertions, 2 deletions

diff --git a/lib/libstand/Makefile b/lib/libstand/Makefile
index 5c207be..ec8aec8 100644
--- a/lib/libstand/Makefile
+++ b/lib/libstand/Makefile
@@ -1,4 +1,4 @@
-# $Id: Makefile,v 1.10 1998/11/04 07:39:53 msmith Exp $
+# $Id: Makefile,v 1.11 1998/11/04 12:49:31 peter Exp $
 #
 # Originally from	$NetBSD: Makefile,v 1.21 1997/10/26 22:08:38 lukem Exp $
 #
@@ -91,7 +91,7 @@ __reml.S: ${.CURDIR}/../libc/alpha/gen/divrem.m4
 SRCS+=	inet_ntoa.c inet_addr.c
 
 # _setjmp/_longjmp
-.PATH:	${.CURDIR}/../libc/${MACHINE_ARCH}/gen
+.PATH:	${.CURDIR}/${MACHINE_ARCH}
 SRCS+=	_setjmp.S
 # really only required for i386
 CFLAGS+=-I${.CURDIR}/../libc/${MACHINE_ARCH}
diff --git a/lib/libstand/alpha/_setjmp.S b/lib/libstand/alpha/_setjmp.S
new file mode 100644
index 0000000..2aa8c55
--- /dev/null
+++ b/lib/libstand/alpha/_setjmp.S
@@ -0,0 +1,123 @@
+/*	$NetBSD: _setjmp.S,v 1.2 1996/10/17 03:08:03 cgd Exp $	*/
+
+/*
+ * Copyright (c) 1994, 1995 Carnegie-Mellon University.
+ * All rights reserved.
+ *
+ * Author: Chris G. Demetriou
+ * 
+ * Permission to use, copy, modify and distribute this software and
+ * its documentation is hereby granted, provided that both the copyright
+ * notice and this permission notice appear in all copies of the
+ * software, derivative works or modified versions, and any portions
+ * thereof, and that both notices appear in supporting documentation.
+ * 
+ * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS" 
+ * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND 
+ * FOR ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
+ * 
+ * Carnegie Mellon requests users of this software to return to
+ *
+ *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
+ *  School of Computer Science
+ *  Carnegie Mellon University
+ *  Pittsburgh PA 15213-3890
+ *
+ * any improvements or extensions that they make and grant Carnegie the
+ * rights to redistribute these changes.
+ */
+
+#include <machine/asm.h>
+
+/*
+ * C library -- _setjmp, _longjmp
+ *
+ *	_longjmp(a,v)
+ * will generate a "return(v)" from
+ * the last call to
+ *	_setjmp(a)
+ * by restoring registers from the stack,
+ * The previous signal state is NOT restored.
+ */
+
+	.set	noreorder
+
+LEAF(_setjmp, 1)
+	LDGP(pv)
+	stq	ra, (2 * 8)(a0)			/* sc_pc = return address */
+	stq	s0, (( 9 + 4) * 8)(a0)		/* saved bits of sc_regs */
+	stq	s1, ((10 + 4) * 8)(a0)
+	stq	s2, ((11 + 4) * 8)(a0)
+	stq	s3, ((12 + 4) * 8)(a0)
+	stq	s4, ((13 + 4) * 8)(a0)
+	stq	s5, ((14 + 4) * 8)(a0)
+	stq	s6, ((15 + 4) * 8)(a0)
+	stq	ra, ((26 + 4) * 8)(a0)
+	stq	sp, ((30 + 4) * 8)(a0)
+	ldiq	t0, 0xacedbadd			/* sigcontext magic number */
+	stq	t0, ((31 + 4) * 8)(a0)		/* magic in sc_regs[31] */
+	/* Too bad we can't check if we actually used FP */
+	ldiq	t0, 1
+	stq	t0, (36 * 8)(a0)		/* say we've used FP.  */
+	stt	fs0, ((2 + 37) * 8)(a0)		/* saved bits of sc_fpregs */
+	stt	fs1, ((3 + 37) * 8)(a0)
+	stt	fs2, ((4 + 37) * 8)(a0)
+	stt	fs3, ((5 + 37) * 8)(a0)
+	stt	fs4, ((6 + 37) * 8)(a0)
+	stt	fs5, ((7 + 37) * 8)(a0)
+	stt	fs6, ((8 + 37) * 8)(a0)
+	stt	fs7, ((9 + 37) * 8)(a0)
+	mf_fpcr ft0				/* get FP control reg */
+	stt	ft0, (69 * 8)(a0)		/* and store it in sc_fpcr */
+	stq	zero, (70 * 8)(a0)		/* FP software control XXX */
+	stq	zero, (71 * 8)(a0)		/* sc_reserved[0] */
+	stq	zero, (72 * 8)(a0)		/* sc_reserved[1] */
+	stq	zero, (73 * 8)(a0)		/* sc_xxx[0] */
+	stq	zero, (74 * 8)(a0)		/* sc_xxx[1] */
+	stq	zero, (75 * 8)(a0)		/* sc_xxx[2] */
+	stq	zero, (76 * 8)(a0)		/* sc_xxx[3] */
+	stq	zero, (77 * 8)(a0)		/* sc_xxx[4] */
+	stq	zero, (78 * 8)(a0)		/* sc_xxx[5] */
+	stq	zero, (79 * 8)(a0)		/* sc_xxx[6] */
+	stq	zero, (80 * 8)(a0)		/* sc_xxx[7] */
+
+	mov	zero, v0			/* return zero */
+	RET
+END(_setjmp)
+
+LEAF(_longjmp, 2)
+	LDGP(pv)
+	ldq	t0, ((31 + 4) * 8)(a0)		/* magic in sc_regs[31] */
+	ldiq	t1, 0xacedbadd
+	cmpeq	t0, t1, t0
+	beq	t0, botch			/* If the magic was bad, punt */
+
+	ldq	ra, (2 * 8)(a0)			/* sc_pc = return address */
+	ldq	s0, (( 9 + 4) * 8)(a0)		/* saved bits of sc_regs */
+	ldq	s1, ((10 + 4) * 8)(a0)
+	ldq	s2, ((11 + 4) * 8)(a0)
+	ldq	s3, ((12 + 4) * 8)(a0)
+	ldq	s4, ((13 + 4) * 8)(a0)
+	ldq	s5, ((14 + 4) * 8)(a0)
+	ldq	s6, ((15 + 4) * 8)(a0)
+	/* ldq	ra, ((26 + 4) * 8)(a0)		set above */
+	ldq	sp, ((30 + 4) * 8)(a0)
+	ldt	fs0, ((2 + 37) * 8)(a0)		/* saved bits of sc_fpregs */
+	ldt	fs1, ((3 + 37) * 8)(a0)
+	ldt	fs2, ((4 + 37) * 8)(a0)
+	ldt	fs3, ((5 + 37) * 8)(a0)
+	ldt	fs4, ((6 + 37) * 8)(a0)
+	ldt	fs5, ((7 + 37) * 8)(a0)
+	ldt	fs6, ((8 + 37) * 8)(a0)
+	ldt	fs7, ((9 + 37) * 8)(a0)
+	ldt	ft0, (69 * 8)(a0)		/* get sc_fpcr */
+	mt_fpcr	ft0				/* and restore it. */
+
+	mov	a1, v0				/* return second arg */
+	RET
+
+botch:
+	CALL(longjmperror)
+	CALL(abort)
+	RET					/* "can't" get here... */
+END(_longjmp)
diff --git a/lib/libstand/i386/_setjmp.S b/lib/libstand/i386/_setjmp.S
new file mode 100644
index 0000000..ba9cc2e
--- /dev/null
+++ b/lib/libstand/i386/_setjmp.S
@@ -0,0 +1,84 @@
+/*-
+ * Copyright (c) 1990 The Regents of the University of California.
+ * All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * William Jolitz.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. All advertising materials mentioning features or use of this software
+ *    must display the following acknowledgement:
+ *	This product includes software developed by the University of
+ *	California, Berkeley and its contributors.
+ * 4. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ *
+ *	$Id: _setjmp.S,v 1.7 1998/04/29 09:14:35 jb Exp $
+ */
+
+#if defined(LIBC_RCS) && !defined(lint)
+	.text
+	.asciz "$Id: _setjmp.S,v 1.7 1998/04/29 09:14:35 jb Exp $"
+#endif /* LIBC_RCS and not lint */
+
+/*
+ * C library -- _setjmp, _longjmp
+ *
+ *	_longjmp(a,v)
+ * will generate a "return(v)" from the last call to
+ *	_setjmp(a)
+ * by restoring registers from the environment 'a'.
+ * The previous signal state is NOT restored.
+ */
+
+#include "DEFS.h"
+
+ENTRY(_setjmp)
+	movl	4(%esp),%eax
+	movl	0(%esp),%edx
+	movl	%edx, 0(%eax)		/* rta */
+	movl	%ebx, 4(%eax)
+	movl	%esp, 8(%eax)
+	movl	%ebp,12(%eax)
+	movl	%esi,16(%eax)
+	movl	%edi,20(%eax)
+	fnstcw	28(%eax)
+	xorl	%eax,%eax
+	ret
+
+ENTRY(_longjmp)
+	movl	4(%esp),%edx
+	movl	8(%esp),%eax
+	movl	0(%edx),%ecx
+	movl	4(%edx),%ebx
+	movl	8(%edx),%esp
+	movl	12(%edx),%ebp
+	movl	16(%edx),%esi
+	movl	20(%edx),%edi
+	fninit
+	fldcw	28(%edx)
+	testl	%eax,%eax
+	jnz	1f
+	incl	%eax
+1:	movl	%ecx,0(%esp)
+	ret