Add mips support libc from the mips2-jnpr branch of perforce.

11 files changed, 836 insertions, 0 deletions

diff --git a/lib/libc/mips/string/Makefile.inc b/lib/libc/mips/string/Makefile.inc
new file mode 100644
index 0000000..48111e5
--- /dev/null
+++ b/lib/libc/mips/string/Makefile.inc
@@ -0,0 +1,8 @@
+#	$NetBSD: Makefile.inc,v 1.2 2000/10/10 21:51:54 jeffs Exp $
+# $FreeBSD$
+
+SRCS+=	bcmp.S bcopy.S bzero.S  ffs.S index.S memchr.c memcmp.c memset.c \
+	memcpy.S memmove.S \
+	rindex.S strcat.c strcmp.S strcpy.c strcspn.c strlen.S \
+	strncat.c strncmp.c strncpy.c strpbrk.c strsep.c \
+	strspn.c strstr.c swab.c
diff --git a/lib/libc/mips/string/bcmp.S b/lib/libc/mips/string/bcmp.S
new file mode 100644
index 0000000..7b7fa68
--- /dev/null
+++ b/lib/libc/mips/string/bcmp.S
@@ -0,0 +1,134 @@
+/*	$NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)bcmp.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+/* bcmp(s1, s2, n) */
+
+
+LEAF(bcmp)
+	.set	noreorder
+	blt	a2, 16, small		# is it worth any trouble?
+	xor	v0, a0, a1		# compare low two bits of addresses
+	and	v0, v0, 3
+	subu	a3, zero, a1		# compute # bytes to word align address
+	bne	v0, zero, unaligned	# not possible to align addresses
+	and	a3, a3, 3
+
+	beq	a3, zero, 1f
+	subu	a2, a2, a3		# subtract from remaining count
+	move	v0, v1			# init v0,v1 so unmodified bytes match
+#ifdef __MIPSEB__
+	lwl	v0, 0(a0)		# read 1, 2, or 3 bytes
+	lwl	v1, 0(a1)
+#else
+	lwr	v0, 0(a0)		# read 1, 2, or 3 bytes
+	lwr	v1, 0(a1)
+#endif
+	addu	a1, a1, a3
+	bne	v0, v1, nomatch
+	addu	a0, a0, a3
+1:
+	and	a3, a2, ~3		# compute number of whole words left
+	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
+	addu	a3, a3, a0		# compute ending address
+2:
+	lw	v0, 0(a0)		# compare words
+	lw	v1, 0(a1)
+	addu	a0, a0, 4
+	bne	v0, v1, nomatch
+	addu	a1, a1, 4
+	bne	a0, a3, 2b
+	nop
+	b	small			# finish remainder
+	nop
+unaligned:
+	beq	a3, zero, 2f
+	subu	a2, a2, a3		# subtract from remaining count
+	addu	a3, a3, a0		# compute ending address
+1:
+	lbu	v0, 0(a0)		# compare bytes until a1 word aligned
+	lbu	v1, 0(a1)
+	addu	a0, a0, 1
+	bne	v0, v1, nomatch
+	addu	a1, a1, 1
+	bne	a0, a3, 1b
+	nop
+2:
+	and	a3, a2, ~3		# compute number of whole words left
+	subu	a2, a2, a3		#   which has to be >= (16-3) & ~3
+	addu	a3, a3, a0		# compute ending address
+3:
+#ifdef __MIPSEB__
+	lwl	v0, 0(a0)		# compare words a0 unaligned, a1 aligned
+	lwr	v0, 3(a0)
+#else
+	lwr	v0, 0(a0)		# compare words a0 unaligned, a1 aligned
+	lwl	v0, 3(a0)
+#endif
+	lw	v1, 0(a1)
+	addu	a0, a0, 4
+	bne	v0, v1, nomatch
+	addu	a1, a1, 4
+	bne	a0, a3, 3b
+	nop
+small:
+	ble	a2, zero, match
+	addu	a3, a2, a0		# compute ending address
+1:
+	lbu	v0, 0(a0)
+	lbu	v1, 0(a1)
+	addu	a0, a0, 1
+	bne	v0, v1, nomatch
+	addu	a1, a1, 1
+	bne	a0, a3, 1b
+	nop
+match:
+	j	ra
+	move	v0, zero
+nomatch:
+	j	ra
+	li	v0, 1
+	.set	reorder
+END(bcmp)
diff --git a/lib/libc/mips/string/bcopy.S b/lib/libc/mips/string/bcopy.S
new file mode 100644
index 0000000..6287d06
--- /dev/null
+++ b/lib/libc/mips/string/bcopy.S
@@ -0,0 +1,300 @@
+/*	$NetBSD: bcopy.S,v 1.2 2005/12/27 11:23:53 tsutsui Exp $	*/
+
+/*
+ * Mach Operating System
+ * Copyright (c) 1993 Carnegie Mellon University
+ * All Rights Reserved.
+ *
+ * Permission to use, copy, modify and distribute this software and its
+ * documentation is hereby granted, provided that both the copyright
+ * notice and this permission notice appear in all copies of the
+ * software, derivative works or modified versions, and any portions
+ * thereof, and that both notices appear in supporting documentation.
+ *
+ * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
+ * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
+ * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
+ *
+ * Carnegie Mellon requests users of this software to return to
+ *
+ *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
+ *  School of Computer Science
+ *  Carnegie Mellon University
+ *  Pittsburgh PA 15213-3890
+ *
+ * any improvements or extensions that they make and grant Carnegie Mellon
+ * the rights to redistribute these changes.
+ */
+
+/*
+ *	File:	mips_bcopy.s
+ *	Author:	Chris Maeda
+ *	Date:	June 1993
+ *
+ *	Fast copy routine.  Derived from aligned_block_copy.
+ */
+
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)mips_bcopy.s	2.2 CMU 18/06/93")
+	ASMSTR("$NetBSD: bcopy.S,v 1.2 2005/12/27 11:23:53 tsutsui Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+/*
+ *	bcopy(caddr_t src, caddr_t dst, unsigned int len)
+ *
+ *	a0 	src address
+ *	a1	dst address
+ *	a2	length
+ */
+
+#if defined(MEMCOPY) || defined(MEMMOVE)
+#ifdef MEMCOPY
+#define	FUNCTION	memcpy
+#else
+#define FUNCTION	memmove
+#endif
+#define	SRCREG		a1
+#define	DSTREG		a0
+#else
+#define	FUNCTION	bcopy
+#define	SRCREG		a0
+#define	DSTREG		a1
+#endif
+
+#define	SIZEREG		a2
+
+LEAF(FUNCTION)
+	.set	noat
+	.set	noreorder
+
+#if defined(MEMCOPY) || defined(MEMMOVE)
+	/* set up return value, while we still can */
+	move	v0,DSTREG
+#endif
+	/*
+	 *	Make sure we can copy forwards.
+	 */
+	sltu	t0,SRCREG,DSTREG	# t0 == SRCREG < DSTREG
+	bne	t0,zero,6f		# copy backwards
+
+	/*
+	 * 	There are four alignment cases (with frequency)
+	 *	(Based on measurements taken with a DECstation 5000/200
+	 *	 inside a Mach kernel.)
+	 *
+	 * 	aligned   -> aligned		(mostly)
+	 * 	unaligned -> aligned		(sometimes)
+	 * 	aligned,unaligned -> unaligned	(almost never)
+	 *
+	 *	Note that we could add another case that checks if
+	 *	the destination and source are unaligned but the
+	 *	copy is alignable.  eg if src and dest are both
+	 *	on a halfword boundary.
+	 */
+	andi	t1,DSTREG,3		# get last 3 bits of dest
+	bne	t1,zero,3f
+	andi	t0,SRCREG,3		# get last 3 bits of src
+	bne	t0,zero,5f
+
+	/*
+	 *	Forward aligned->aligned copy, 8*4 bytes at a time.
+	 */
+	li	AT,-32
+	and	t0,SIZEREG,AT		# count truncated to multiple of 32 */
+	addu	a3,SRCREG,t0		# run fast loop up to this address
+	sltu	AT,SRCREG,a3		# any work to do?
+	beq	AT,zero,2f
+	subu	SIZEREG,t0
+
+	/*
+	 *	loop body
+	 */
+1:	# cp
+	lw	t3,0(SRCREG)
+	lw	v1,4(SRCREG)
+	lw	t0,8(SRCREG)
+	lw	t1,12(SRCREG)
+	addu	SRCREG,32
+	sw	t3,0(DSTREG)
+	sw	v1,4(DSTREG)
+	sw	t0,8(DSTREG)
+	sw	t1,12(DSTREG)
+	lw	t1,-4(SRCREG)
+	lw	t0,-8(SRCREG)
+	lw	v1,-12(SRCREG)
+	lw	t3,-16(SRCREG)
+	addu	DSTREG,32
+	sw	t1,-4(DSTREG)
+	sw	t0,-8(DSTREG)
+	sw	v1,-12(DSTREG)
+	bne	SRCREG,a3,1b
+	sw	t3,-16(DSTREG)
+
+	/*
+	 *	Copy a word at a time, no loop unrolling.
+	 */
+2:	# wordcopy
+	andi	t2,SIZEREG,3		# get byte count / 4
+	subu	t2,SIZEREG,t2		# t2 = number of words to copy * 4
+	beq	t2,zero,3f
+	addu	t0,SRCREG,t2		# stop at t0
+	subu	SIZEREG,SIZEREG,t2
+1:
+	lw	t3,0(SRCREG)
+	addu	SRCREG,4
+	sw	t3,0(DSTREG)
+	bne	SRCREG,t0,1b
+	addu	DSTREG,4
+
+3:	# bytecopy
+	beq	SIZEREG,zero,4f	# nothing left to do?
+	nop
+1:
+	lb	t3,0(SRCREG)
+	addu	SRCREG,1
+	sb	t3,0(DSTREG)
+	subu	SIZEREG,1
+	bgtz	SIZEREG,1b
+	addu	DSTREG,1
+
+4:	# copydone
+	j	ra
+	nop
+
+	/*
+	 *	Copy from unaligned source to aligned dest.
+	 */
+5:	# destaligned
+	andi	t0,SIZEREG,3		# t0 = bytecount mod 4
+	subu	a3,SIZEREG,t0		# number of words to transfer
+	beq	a3,zero,3b
+	nop
+	move	SIZEREG,t0		# this many to do after we are done
+	addu	a3,SRCREG,a3		# stop point
+
+1:
+#ifdef __MIPSEB__
+	lwl	t3,0(SRCREG)
+	lwr	t3,3(SRCREG)
+#else
+	lwr	t3,0(SRCREG)
+	lwl	t3,3(SRCREG)
+#endif
+	addi	SRCREG,4
+	sw	t3,0(DSTREG)
+	bne	SRCREG,a3,1b
+	addi	DSTREG,4
+
+	j	3b
+	nop
+
+6:	# backcopy -- based on above
+	addu	SRCREG,SIZEREG
+	addu	DSTREG,SIZEREG
+	andi	t1,DSTREG,3		# get last 3 bits of dest
+	bne	t1,zero,3f
+	andi	t0,SRCREG,3		# get last 3 bits of src
+	bne	t0,zero,5f
+
+	/*
+	 *	Forward aligned->aligned copy, 8*4 bytes at a time.
+	 */
+	li	AT,-32
+	and	t0,SIZEREG,AT		# count truncated to multiple of 32
+	beq	t0,zero,2f		# any work to do?
+	subu	SIZEREG,t0
+	subu	a3,SRCREG,t0
+
+	/*
+	 *	loop body
+	 */
+1:	# cp
+	lw	t3,-16(SRCREG)
+	lw	v1,-12(SRCREG)
+	lw	t0,-8(SRCREG)
+	lw	t1,-4(SRCREG)
+	subu	SRCREG,32
+	sw	t3,-16(DSTREG)
+	sw	v1,-12(DSTREG)
+	sw	t0,-8(DSTREG)
+	sw	t1,-4(DSTREG)
+	lw	t1,12(SRCREG)
+	lw	t0,8(SRCREG)
+	lw	v1,4(SRCREG)
+	lw	t3,0(SRCREG)
+	subu	DSTREG,32
+	sw	t1,12(DSTREG)
+	sw	t0,8(DSTREG)
+	sw	v1,4(DSTREG)
+	bne	SRCREG,a3,1b
+	sw	t3,0(DSTREG)
+
+	/*
+	 *	Copy a word at a time, no loop unrolling.
+	 */
+2:	# wordcopy
+	andi	t2,SIZEREG,3		# get byte count / 4
+	subu	t2,SIZEREG,t2		# t2 = number of words to copy * 4
+	beq	t2,zero,3f
+	subu	t0,SRCREG,t2		# stop at t0
+	subu	SIZEREG,SIZEREG,t2
+1:
+	lw	t3,-4(SRCREG)
+	subu	SRCREG,4
+	sw	t3,-4(DSTREG)
+	bne	SRCREG,t0,1b
+	subu	DSTREG,4
+
+3:	# bytecopy
+	beq	SIZEREG,zero,4f		# nothing left to do?
+	nop
+1:
+	lb	t3,-1(SRCREG)
+	subu	SRCREG,1
+	sb	t3,-1(DSTREG)
+	subu	SIZEREG,1
+	bgtz	SIZEREG,1b
+	subu	DSTREG,1
+
+4:	# copydone
+	j	ra
+	nop
+
+	/*
+	 *	Copy from unaligned source to aligned dest.
+	 */
+5:	# destaligned
+	andi	t0,SIZEREG,3		# t0 = bytecount mod 4
+	subu	a3,SIZEREG,t0		# number of words to transfer
+	beq	a3,zero,3b
+	nop
+	move	SIZEREG,t0		# this many to do after we are done
+	subu	a3,SRCREG,a3		# stop point
+
+1:
+#ifdef __MIPSEB__
+	lwl	t3,-4(SRCREG)
+	lwr	t3,-1(SRCREG)
+#else
+	lwr	t3,-4(SRCREG)
+	lwl	t3,-1(SRCREG)
+#endif
+	subu	SRCREG,4
+	sw	t3,-4(DSTREG)
+	bne	SRCREG,a3,1b
+	subu	DSTREG,4
+
+	j	3b
+	nop
+
+	.set	reorder
+	.set	at
+	END(FUNCTION)
diff --git a/lib/libc/mips/string/bzero.S b/lib/libc/mips/string/bzero.S
new file mode 100644
index 0000000..9b34130
--- /dev/null
+++ b/lib/libc/mips/string/bzero.S
@@ -0,0 +1,82 @@
+/*	$NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)bzero.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+/* bzero(s1, n) */
+
+LEAF(bzero)
+	.set	noreorder
+	blt	a1, 12, smallclr	# small amount to clear?
+	subu	a3, zero, a0		# compute # bytes to word align address
+	and	a3, a3, 3
+	beq	a3, zero, 1f		# skip if word aligned
+	subu	a1, a1, a3		# subtract from remaining count
+#ifdef __MIPSEB__
+	swl	zero, 0(a0)		# clear 1, 2, or 3 bytes to align
+#else
+	swr	zero, 0(a0)		# clear 1, 2, or 3 bytes to align
+#endif
+	addu	a0, a0, a3
+1:
+	and	v0, a1, 3		# compute number of words left
+	subu	a3, a1, v0
+	move	a1, v0
+	addu	a3, a3, a0		# compute ending address
+2:
+	addu	a0, a0, 4		# clear words
+	bne	a0, a3, 2b		#   unrolling loop doesnt help
+	sw	zero, -4(a0)		#   since we are limited by memory speed
+smallclr:
+	ble	a1, zero, 2f
+	addu	a3, a1, a0		# compute ending address
+1:
+	addu	a0, a0, 1		# clear bytes
+	bne	a0, a3, 1b
+	sb	zero, -1(a0)
+2:
+	j	ra
+	nop
+END(bzero)
diff --git a/lib/libc/mips/string/ffs.S b/lib/libc/mips/string/ffs.S
new file mode 100644
index 0000000..8df2be3
--- /dev/null
+++ b/lib/libc/mips/string/ffs.S
@@ -0,0 +1,59 @@
+/*	$NetBSD: ffs.S,v 1.1 2005/12/20 19:28:49 christos Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)ffs.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: ffs.S,v 1.1 2005/12/20 19:28:49 christos Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+/* bit = ffs(value) */
+
+LEAF(ffs)
+	move	v0, zero
+	beq	a0, zero, done
+1:
+	and	v1, a0, 1		# bit set?
+	addu	v0, v0, 1
+	srl	a0, a0, 1
+	beq	v1, zero, 1b		# no, continue
+done:
+	j	ra
+END(ffs)
diff --git a/lib/libc/mips/string/index.S b/lib/libc/mips/string/index.S
new file mode 100644
index 0000000..055baac
--- /dev/null
+++ b/lib/libc/mips/string/index.S
@@ -0,0 +1,59 @@
+/*	$NetBSD: index.S,v 1.8 2005/04/22 06:59:00 simonb Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)index.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: index.S,v 1.8 2005/04/22 06:59:00 simonb Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+LEAF(index)
+1:
+	lbu	a2, 0(a0)		# get a byte
+	addu	a0, a0, 1
+	beq	a2, a1, fnd
+	bne	a2, zero, 1b
+notfnd:
+	move	v0, zero
+	j	ra
+fnd:
+	subu	v0, a0, 1
+	j	ra
+END(index)
diff --git a/lib/libc/mips/string/memcpy.S b/lib/libc/mips/string/memcpy.S
new file mode 100644
index 0000000..8d3c0db
--- /dev/null
+++ b/lib/libc/mips/string/memcpy.S
@@ -0,0 +1,7 @@
+/*	$NetBSD: memcpy.S,v 1.1 2005/12/20 19:28:50 christos Exp $	*/
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#define MEMCOPY
+#include "bcopy.S"
diff --git a/lib/libc/mips/string/memmove.S b/lib/libc/mips/string/memmove.S
new file mode 100644
index 0000000..29d9e70
--- /dev/null
+++ b/lib/libc/mips/string/memmove.S
@@ -0,0 +1,7 @@
+/*	$NetBSD: memmove.S,v 1.1 2005/12/20 19:28:50 christos Exp $	*/
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#define MEMMOVE
+#include "bcopy.S"
diff --git a/lib/libc/mips/string/rindex.S b/lib/libc/mips/string/rindex.S
new file mode 100644
index 0000000..60cbb48
--- /dev/null
+++ b/lib/libc/mips/string/rindex.S
@@ -0,0 +1,57 @@
+/*	$NetBSD: rindex.S,v 1.7 2003/08/07 16:42:16 agc Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)rindex.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: rindex.S,v 1.7 2003/08/07 16:42:16 agc Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+LEAF(rindex)
+	move	v0, zero		# default if not found
+1:
+	lbu	a3, 0(a0)		# get a byte
+	addu	a0, a0, 1
+	bne	a3, a1, 2f
+	subu	v0, a0, 1		# save address of last match
+2:
+	bne	a3, zero, 1b		# continue if not end
+	j	ra
+END(rindex)
diff --git a/lib/libc/mips/string/strcmp.S b/lib/libc/mips/string/strcmp.S
new file mode 100644
index 0000000..ce2839d
--- /dev/null
+++ b/lib/libc/mips/string/strcmp.S
@@ -0,0 +1,68 @@
+/*	$NetBSD: strcmp.S,v 1.1 2005/12/20 19:28:50 christos Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)strcmp.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: strcmp.S,v 1.1 2005/12/20 19:28:50 christos Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+/*
+ * NOTE: this version assumes unsigned chars in order to be "8 bit clean".
+ */
+LEAF(strcmp)
+1:
+	lbu	t0, 0(a0)		# get two bytes and compare them
+	lbu	t1, 0(a1)
+	beq	t0, zero, LessOrEq	# end of first string?
+	bne	t0, t1, NotEq
+	lbu	t0, 1(a0)		# unroll loop
+	lbu	t1, 1(a1)
+	add	a0, a0, 2
+	beq	t0, zero, LessOrEq	# end of first string?
+	add	a1, a1, 2
+	beq	t0, t1, 1b
+NotEq:
+	subu	v0, t0, t1
+	j	ra
+LessOrEq:
+	subu	v0, zero, t1
+	j	ra
+END(strcmp)
diff --git a/lib/libc/mips/string/strlen.S b/lib/libc/mips/string/strlen.S
new file mode 100644
index 0000000..c1f302d
--- /dev/null
+++ b/lib/libc/mips/string/strlen.S
@@ -0,0 +1,55 @@
+/*	$NetBSD: strlen.S,v 1.1 2005/12/20 19:28:50 christos Exp $	*/
+
+/*-
+ * Copyright (c) 1991, 1993
+ *	The Regents of the University of California.  All rights reserved.
+ *
+ * This code is derived from software contributed to Berkeley by
+ * Ralph Campbell.
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ * 3. Neither the name of the University nor the names of its contributors
+ *    may be used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
+ * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+ * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
+ * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+ * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
+ * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
+ * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
+ * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
+ * SUCH DAMAGE.
+ */
+
+#include <machine/asm.h>
+__FBSDID("$FreeBSD$");
+
+#if defined(LIBC_SCCS) && !defined(lint)
+	ASMSTR("from: @(#)strlen.s	8.1 (Berkeley) 6/4/93")
+	ASMSTR("$NetBSD: strlen.S,v 1.1 2005/12/20 19:28:50 christos Exp $")
+#endif /* LIBC_SCCS and not lint */
+
+#ifdef __ABICALLS__
+	.abicalls
+#endif
+
+LEAF(strlen)
+	addu	v1, a0, 1
+1:
+	lb	v0, 0(a0)		# get byte from string
+	addu	a0, a0, 1		# increment pointer
+	bne	v0, zero, 1b		# continue if not end
+	subu	v0, a0, v1		# compute length - 1 for '\0' char
+	j	ra
+END(strlen)