Virgin import of GCC 2.95.1's libobjc.

(previous GCC/EGCS versions had these files in gcc/objc/)

1 files changed, 142 insertions, 0 deletions

diff --git a/contrib/libobjc/configure.in b/contrib/libobjc/configure.in
new file mode 100644
index 0000000..821dcd2
--- /dev/null
+++ b/contrib/libobjc/configure.in
@@ -0,0 +1,142 @@
+# Process this file with autoconf to produce a configure script.
+#   Copyright (C) 1995, 1997, 1998, 1999 Free Software Foundation, Inc.
+#   Contributed by Dave Love (d.love@dl.ac.uk).
+#
+#This file is part of GNU Objective C.
+#
+#GNU Objective C is free software; you can redistribute it and/or modify
+#it under the terms of the GNU General Public License as published by
+#the Free Software Foundation; either version 2, or (at your option)
+#any later version.
+#
+#GNU Objective C is distributed in the hope that it will be useful,
+#but WITHOUT ANY WARRANTY; without even the implied warranty of
+#MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+#GNU General Public License for more details.
+#
+#You should have received a copy of the GNU General Public License
+#along with GNU Objective C; see the file COPYING.  If not, write to
+#the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
+#02111-1307, USA.
+
+AC_PREREQ(2.13)
+AC_INIT(objc/objc.h)
+#AC_CONFIG_HEADER(config.h)
+
+if test "${srcdir}" = "." ; then
+  if test "${with_target_subdir}" != "." ; then
+    topsrcdir=${with_multisrctop}../..
+  else
+    topsrcdir=${with_multisrctop}..
+  fi
+else
+  topsrcdir=${srcdir}/..
+fi
+dnl This is needed for a multilibbed build in the source tree so
+dnl that install-sh and config.sub get found.
+AC_CONFIG_AUX_DIR($topsrcdir)
+
+# If the language specific compiler does not exist, but the "gcc" directory 
+# does, we do not build anything. Note, $r is set by the top-level Makefile.
+# Note that when we look for the compiler, we search both with and without
+# extension to handle cross and canadian cross builds. 
+compiler_name=cc1obj
+rm -f skip-this-dir
+AC_MSG_CHECKING(if compiler $compiler_name has been built)
+AC_CACHE_VAL(objc_cv_compiler_exists,
+[objc_cv_compiler_exists=yes
+if test -n "$r"; then
+  if test -d "$r"/gcc; then
+    if test -f "$r"/gcc/$compiler_name \
+       || test -f "$r"/gcc/$compiler_name.exe; then
+      true
+    else
+      objc_cv_compiler_exists=no
+      echo "rm -f config.cache config.log multilib.out" > skip-this-dir
+    fi
+  fi
+fi
+])
+AC_MSG_RESULT($objc_cv_compiler_exists)
+if test x$objc_cv_compiler_exists = xno
+then
+  rm -f Makefile conftest* confdefs* core
+  exit 0
+fi
+
+dnl Checks for programs.
+# For ObjC we'll set CC to point at the built gcc, but this will get it into
+# the makefiles
+AC_PROG_CC
+
+test "$AR" || AR=ar
+AC_SUBST(AR)
+if test "$RANLIB"; then :
+  AC_SUBST(RANLIB)
+else
+  AC_PROG_RANLIB
+fi
+AC_PROG_INSTALL
+
+dnl Checks for libraries.
+
+dnl Checks for header files.
+# Sanity check for the cross-compilation case:
+AC_CHECK_HEADER(stdio.h,:,
+  [AC_MSG_ERROR([Can't find stdio.h.
+You must have a usable C system for the target already installed, at least
+including headers and, preferably, the library, before you can configure
+the Objective C runtime system.  If necessary, install gcc now with 
+\`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
+
+AC_HEADER_STDC
+
+# Determine the name of the GCC thread file.
+
+AC_CACHE_CHECK([for thread file],objc_cv_thread_file,
+[if test -f "$r"/gcc/Makefile
+then
+  objc_cv_thread_file=`grep \^GCC_THREAD_FILE "$r"/gcc/Makefile | awk -F= '{ print $2 }'`
+else
+  AC_MSG_ERROR([not found])
+fi])
+OBJC_THREAD_FILE=$objc_cv_thread_file
+AC_SUBST(OBJC_THREAD_FILE)
+
+AC_ARG_ENABLE(objc-gc,
+[  --enable-objc-gc       enable the use of Boehm's garbage collector with
+                          the GNU Objective-C runtime.],
+if [[[ x$enable_objc_gc = xno ]]]; then
+        OBJC_BOEHM_GC=''
+else
+        OBJC_BOEHM_GC=libobjc_gc.a
+fi,
+OBJC_BOEHM_GC='')
+AC_SUBST(OBJC_BOEHM_GC)
+
+
+# We need multilib support, but only if configuring for the target.
+AC_OUTPUT(Makefile,
+[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
+if test -n "$CONFIG_FILES"; then
+  if test -n "${with_target_subdir}"; then
+    # FIXME: We shouldn't need to set ac_file
+    ac_file=Makefile
+    . ${topsrcdir}/config-ml.in
+  fi
+fi],
+srcdir=${srcdir}
+host=${host}
+target=${target}
+with_target_subdir=${with_target_subdir}
+with_multisubdir=${with_multisubdir}
+ac_configure_args="--enable-multilib ${ac_configure_args}"
+CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
+topsrcdir=${topsrcdir}
+)
+
+dnl Local Variables:
+dnl comment-start: "dnl "
+dnl comment-end: ""
+dnl comment-start-skip: "\\bdnl\\b\\s *"
+dnl End: